harry11733
Member
The project that I am working on requires short (20-50 ms) bursts of white noise (75 to 125 dB) over a constant background of low volume white noise (65-68 dB). The wide dynamic range (60 dB) required to do this just exceeds the dynamic range of the DAC (A14: 12 bit resolution), using my particular speakers and amp.
I am thinking of switching to using the audio board (16 bit resolution) to solve this problem, but I am reluctant to change because everything else is working quite well. The code is shown below. The board is driven by commands from a python program.
My questions are:
1. How easy would it be to convert this code to use the audio board?
2. Is the audio board compatible with the Teensy Breakout board? I have found this breakout board to be useful in allowing easy access to the differential inputs of the 2nd ADC since I have to capture two signals during the presentation of the white noise pulse.
I am thinking of switching to using the audio board (16 bit resolution) to solve this problem, but I am reluctant to change because everything else is working quite well. The code is shown below. The board is driven by commands from a python program.
My questions are:
1. How easy would it be to convert this code to use the audio board?
2. Is the audio board compatible with the Teensy Breakout board? I have found this breakout board to be useful in allowing easy access to the differential inputs of the 2nd ADC since I have to capture two signals during the presentation of the white noise pulse.
Code:
#include <ADC.h>
#include "IntervalTimer.h"
// define pins
const int readPin1 = A10; // ADC_0 accelerometer box 1
const int readPin1diff = A11; // ADC_0 accelerometer box 1 differential input
const int readPin2 = A12; // ADC_1 accelerometer box 2
const int readPin2diff = A13; // ADC_1 accelerometer box 2 differential input
const int DACPin = A14; // Audio output
const int ledPin = 13; // use to look at timing
// data storage
const int BUFFERSIZE = 1024;
uint16_t buf0[BUFFERSIZE];
uint16_t buf1[BUFFERSIZE];
byte val[2];
ADC *adc = new ADC(); // adc object
IntervalTimer timer1;
// constants
const int period1 = 50; // us 20kHz
const int baudrate = 115200;
const long DAC_midpoint = 2048; // half of maximum DAC output
// trial parameters
const unsigned long pulse2Start = 200000; // 200 ms, start of second pulse is fixed
int Background_Level = 2; // background noise level
int Background_half = 1; // half background level
int Volume1 = 0; // volume of first pulse
int Volume1_half = 0; // half volume1
unsigned long Duration1 = 0; // duration of first pulse
int Volume2 = 0; // volume of second pulse
int Volume2_half = 0; // half volume2
unsigned long Duration2 = 0; // duration of first pulse
long PulseInterval = 0; // delay between end of first pulse and start of second pulse
unsigned long start = 0; // time at start of trial
void setup() {
// setup DAC
pinMode(DACPin, OUTPUT);
analogWriteResolution(12);
// set up read pins
pinMode(readPin1, INPUT);
pinMode(readPin1diff, INPUT);
pinMode(readPin2, INPUT);
pinMode(readPin2diff, INPUT);
// digital pin
pinMode(ledPin, OUTPUT);
// ADC_0 setup
adc->setAveraging(32, ADC_0); // set number of averages
adc->setResolution(16, ADC_0); // set bits of resolution
adc->setConversionSpeed(ADC_VERY_LOW_SPEED , ADC_0); // change the conversion speed
adc->setSamplingSpeed(ADC_VERY_LOW_SPEED , ADC_0); // change the sampling speed
adc->enablePGA(1, ADC_0); // only works in differential mode
adc->setReference(ADC_REF_3V3, ADC_0);
// ADC_1 setup
adc->setAveraging(32, ADC_1); // set number of averages
adc->setResolution(16, ADC_1); // set bits of resolution
adc->setConversionSpeed(ADC_VERY_LOW_SPEED , ADC_1); // change the conversion speed
adc->setSamplingSpeed(ADC_VERY_LOW_SPEED , ADC_1); // change the sampling speed
adc->enablePGA(1, ADC_1); // only works in differential mode
adc->setReference(ADC_REF_3V3, ADC_1);
timer1.begin(timer1_callback, period1);
Serial.begin(baudrate);
}
void loop() {
while ( Serial.available() > 0 ) {
String inString = Serial.readStringUntil( '\n' );
// parse the string for a command, use 'startsWith' to ignore newline character
if ( inString.startsWith( "handshake" ) ) {
Serial.println("handshake"); // return handshake
} else if ( inString.startsWith( "Background" ) ) {
Background_Level = inString.substring( 10 ).toInt();
Background_half = Background_Level / 2;
} else if ( inString.startsWith( "Volume1" ) ) {
Volume1 = inString.substring( 7 ).toInt();
Volume1_half = Volume1 / 2;
} else if ( inString.startsWith( "Volume2" ) ) {
Volume2 = inString.substring( 7 ).toInt();
Volume2_half = Volume2 / 2;
} else if ( inString.startsWith( "Duration1" ) ) {
Duration1 = inString.substring( 9 ).toInt();
} else if ( inString.startsWith( "Duration2" ) ) {
Duration2 = inString.substring( 9 ).toInt();
} else if ( inString.startsWith( "PulseInterval" ) ) {
PulseInterval = inString.substring( 13 ).toInt();
} else if ( inString.startsWith( "ASR" ) ) {
run_Trial();
} else {
// ignore unknown commands
}
}
} // main loop
void run_Trial (void) {
digitalWrite(ledPin, HIGH);
start = micros(); // determines the start time of the trace, needed to time white noise output
for (int i = 0 ; i < BUFFERSIZE ; i++) {
buf0[i] = adc->analogReadDifferential(readPin1, readPin1diff, ADC_0);
buf1[i] = adc->analogReadDifferential(readPin2, readPin2diff, ADC_1);
} // for
digitalWrite(ledPin, LOW);
// send data as bytes
for (int i = 0; i < BUFFERSIZE; i++) {
val[0] = lowByte(buf0[i]);
val[1] = highByte(buf0[i]);
Serial.write(val, 2);
}
for (int i = 0; i < BUFFERSIZE; i++) {
val[0] = lowByte(buf1[i]);
val[1] = highByte(buf1[i]);
Serial.write(val, 2);
}
Serial.flush();
} // run_Trial
void timer1_callback(void) {
unsigned long timeNow = micros() - start; //time at start of function
// timing of prepulse
if ( (timeNow >= (pulse2Start - Duration1 - PulseInterval)) && (timeNow < (pulse2Start - PulseInterval)) ) {
analogWrite(DACPin, random(-Volume1_half, Volume1_half) + DAC_midpoint);
} // timing of stimulus pulse
else if ( (timeNow >= pulse2Start) && (timeNow < (pulse2Start + Duration2)) ){
analogWrite(DACPin, random(-Volume2_half, Volume2_half) + DAC_midpoint);
}
else {
analogWrite(DACPin, random(-Background_half, Background_half) + DAC_midpoint); // background noise
}
} // timer1_callback
