3 Teensy's with OctoWS2811 not working on Raspberry PI

Status
Not open for further replies.
S

Snazzy

New member
Hey guys!

I got a problem which I do not get fixed.
Hardware setup:
- 3 Teensy's with OctoWS2811
- 2 Teensy's with 8 LED strips, 1 Teensy with 3 LED strips connected
- Raspberry PI 3 Model B (armv7l) Strech

My goal:
Drive the 3 Teensy's (the led strips) with the raspberry pi with the movie2serial script.

I connected and configured everything similar to this OctoWS2811 tutorial. Everything works fine on my MacBook Pro.
So now I want to run this on a raspberry pi but there is a strange behavior. I run the movie2serial script on the pi I run into some gstreamer issues. I found this processing thread to fix this issue. Everything fine - video is playing on the pie.
But now when I start the movie2serial script on the pi only one Teensy display something.
This is the code I am running on the pi in processing (worked on mac):

Code: 
/*  OctoWS2811 movie2serial.pde - Transmit video data to 1 or more
      Teensy 3.0 boards running OctoWS2811 VideoDisplay.ino
    <a href="http://www.pjrc.com/teensy/td_libs_OctoWS2811.html" target="_blank" rel="nofollow">http://www.pjrc.com/teensy/td_libs_OctoWS2811.html</a>
    Copyright (c) 2013 Paul Stoffregen, PJRC.COM, LLC
 
    Permission is hereby granted, free of charge, to any person obtaining a copy
    of this software and associated documentation files (the "Software"), to deal
    in the Software without restriction, including without limitation the rights
    to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
    copies of the Software, and to permit persons to whom the Software is
    furnished to do so, subject to the following conditions:
 
    The above copyright notice and this permission notice shall be included in
    all copies or substantial portions of the Software.
 
    THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
    IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
    FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
    AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
    LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
    OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
    THE SOFTWARE.
*/
 
// To configure this program, edit the following sections:
//
//  1: change myMovie to open a video file of your choice    <span class="Emoticon Emoticon3"><span>;-)</span></span>
//
//  2: edit the serialConfigure() lines in setup() for your
//     serial device names (Mac, Linux) or COM ports (Windows)
//
//  3: if your LED strips have unusual color configuration,
//     edit colorWiring().  Nearly all strips have GRB wiring,
//     so normally you can leave this as-is.
//
//  4: if playing 50 or 60 Hz progressive video (or faster),
//     edit framerate in movieEvent().
 
//import processing.video.*;
import gohai.glvideo.*;
import processing.serial.*;
import java.awt.Rectangle;
 
GLMovie myMovie;
 
float gamma = 1.7;
 
int numPorts=0;  // the number of serial ports in use
int maxPorts=24; // maximum number of serial ports
 
Serial[] ledSerial = new Serial[maxPorts];     // each port's actual Serial port
Rectangle[] ledArea = new Rectangle[maxPorts]; // the area of the movie each port gets, in % (0-100)
boolean[] ledLayout = new boolean[maxPorts];   // layout of rows, true = even is left->right
PImage[] ledImage = new PImage[maxPorts];      // image sent to each port
int[] gammatable = new int[256];
int errorCount=0;
float framerate=0;
 
void setup() {
  String[] list = Serial.list();
  delay(20);
  println("Serial Ports List:");
  println(list);
  serialConfigure("/dev/tty.usbmodem4645681");  // change these to your port names
  serialConfigure("/dev/cu.usbmodem4645891");
  serialConfigure("/dev/tty.usbmodem4793111");
  if (errorCount > 0) exit();
  for (int i=0; i < 256; i++) {
    gammatable[i] = (int)(pow((float)i / 255.0, gamma) * 255.0 + 0.5);
  }
  size(480, 400, P2D);  // create the window
  myMovie = new GLMovie(this, "/home/pi/test.mp4");
  myMovie.loop();  // start the movie <span class="Emoticon Emoticon1"><span>:-)</span></span>
}
 
 
// movieEvent runs for each new frame of movie data
void movieEvent(GLMovie m) {
  // read the movie's next frame
  m.read();
 
  //if (framerate == 0) framerate = m.getSourceFrameRate();
  framerate = 30; // TODO, how to read the frame rate???
 
  for (int i=0; i < numPorts; i++) {    
    // copy a portion of the movie's image to the LED image
    int xoffset = percentage(m.width, ledArea[i].x);
    int yoffset = percentage(m.height, ledArea[i].y);
    int xwidth =  percentage(m.width, ledArea[i].width);
    int yheight = percentage(m.height, ledArea[i].height);
    ledImage[i].copy(m, xoffset, yoffset, xwidth, yheight,
                     0, 0, ledImage[i].width, ledImage[i].height);
    // convert the LED image to raw data
    byte[] ledData =  new byte[(ledImage[i].width * ledImage[i].height * 3) + 3];
    image2data(ledImage[i], ledData, ledLayout[i]);
    if (i == 0) {
      ledData[0] = '*';  // first Teensy is the frame sync master
      int usec = (int)((1000000.0 / framerate) * 0.75);
      ledData[1] = (byte)(usec);   // request the frame sync pulse
      ledData[2] = (byte)(usec >> 8); // at 75% of the frame time
    } else {
      ledData[0] = '%';  // others sync to the master board
      ledData[1] = 0;
      ledData[2] = 0;
    }
    // send the raw data to the LEDs  <span class="Emoticon Emoticon1"><span>:-)</span></span>
    ledSerial[i].write(ledData); 
  }
}
 
// image2data converts an image to OctoWS2811's raw data format.
// The number of vertical pixels in the image must be a multiple
// of 8.  The data array must be the proper size for the image.
void image2data(PImage image, byte[] data, boolean layout) {
  int offset = 3;
  int x, y, xbegin, xend, xinc, mask;
  int linesPerPin = image.height / 8;
  int pixel[] = new int[8];
 
  for (y = 0; y < linesPerPin; y++) {
    if ((y & 1) == (layout ? 0 : 1)) {
      // even numbered rows are left to right
      xbegin = 0;
      xend = image.width;
      xinc = 1;
    } else {
      // odd numbered rows are right to left
      xbegin = image.width - 1;
      xend = -1;
      xinc = -1;
    }
    for (x = xbegin; x != xend; x += xinc) {
      for (int i=0; i < 8; i++) {
        // fetch 8 pixels from the image, 1 for each pin
        pixel[i] = image.pixels[x + (y + linesPerPin * i) * image.width];
        pixel[i] = colorWiring(pixel[i]);
      }
      // convert 8 pixels to 24 bytes
      for (mask = 0x800000; mask != 0; mask >>= 1) {
        byte b = 0;
        for (int i=0; i < 8; i++) {
          if ((pixel[i] & mask) != 0) b |= (1 << i);
        }
        data[offset++] = b;
      }
    }
  } 
}
 
// translate the 24 bit color from RGB to the actual
// order used by the LED wiring.  GRB is the most common.
int colorWiring(int c) {
  int red = (c & 0xFF0000) >> 16;
  int green = (c & 0x00FF00) >> 8;
  int blue = (c & 0x0000FF);
  red = gammatable[red];
  green = gammatable[green];
  blue = gammatable[blue];
  return (green << 16) | (red << 8) | (blue); // GRB - most common wiring
}
 
// ask a Teensy board for its LED configuration, and set up the info for it.
void serialConfigure(String portName) {
  if (numPorts >= maxPorts) {
    println("too many serial ports, please increase maxPorts");
    errorCount++;
    return;
  }
  try {
    ledSerial[numPorts] = new Serial(this, portName);
    if (ledSerial[numPorts] == null) throw new NullPointerException();
    ledSerial[numPorts].write('?');
  } catch (Throwable e) {
    println("Serial port " + portName + " does not exist or is non-functional");
    errorCount++;
    return;
  }
  delay(250);
  String line = ledSerial[numPorts].readStringUntil(10);
  if (line == null) {
    println("Serial port " + portName + " is not responding.");
    println("Is it really a Teensy 3.0 running VideoDisplay?");
    errorCount++;
    return;
  }
  String param[] = line.split(",");
  if (param.length != 12) {
    println("Error: port " + portName + " did not respond to LED config query");
    errorCount++;
    return;
  }
  // only store the info and increase numPorts if Teensy responds properly
  ledImage[numPorts] = new PImage(Integer.parseInt(param[0]), Integer.parseInt(param[1]), RGB);
  ledArea[numPorts] = new Rectangle(Integer.parseInt(param[5]), Integer.parseInt(param[6]),
                     Integer.parseInt(param[7]), Integer.parseInt(param[8]));
  ledLayout[numPorts] = (Integer.parseInt(param[5]) == 0);
  numPorts++;
}
 
// draw runs every time the screen is redrawn - show the movie...
void draw() {
  if (myMovie.available()) {
    movieEvent(myMovie);
  }
 
 
  // show the original video
  image(myMovie, 0, 80);
 
  // then try to show what was most recently sent to the LEDs
  // by displaying all the images for each port.
  for (int i=0; i < numPorts; i++) {
    // compute the intended size of the entire LED array
    int xsize = percentageInverse(ledImage[i].width, ledArea[i].width);
    int ysize = percentageInverse(ledImage[i].height, ledArea[i].height);
    // computer this image's position within it
    int xloc =  percentage(xsize, ledArea[i].x);
    int yloc =  percentage(ysize, ledArea[i].y);
    // show what should appear on the LEDs
    image(ledImage[i], 240 - xsize / 2 + xloc, 10 + yloc);
  } 
}
 
// respond to mouse clicks as pause/play
boolean isPlaying = true;
void mousePressed() {
  if (isPlaying) {
    myMovie.pause();
    isPlaying = false;
  } else {
    myMovie.play();
    isPlaying = true;
  }
}
 
// scale a number by a percentage, from 0 to 100
int percentage(int num, int percent) {
  double mult = percentageFloat(percent);
  double output = num * mult;
  return (int)output;
}
 
// scale a number by the inverse of a percentage, from 0 to 100
int percentageInverse(int num, int percent) {
  double div = percentageFloat(percent);
  double output = num / div;
  return (int)output;
}
 
// convert an integer from 0 to 100 to a float percentage
// from 0.0 to 1.0.  Special cases for 1/3, 1/6, 1/7, etc
// are handled automatically to fix integer rounding.
double percentageFloat(int percent) {
  if (percent == 33) return 1.0 / 3.0;
  if (percent == 17) return 1.0 / 6.0;
  if (percent == 14) return 1.0 / 7.0;
  if (percent == 13) return 1.0 / 8.0;
  if (percent == 11) return 1.0 / 9.0;
  if (percent ==  9) return 1.0 / 11.0;
  if (percent ==  8) return 1.0 / 12.0;
  return (double)percent / 100.0;
}

Only the first usb port which I define with "serialConfigure()" is working. If I remove the first, the second is working. I tried to use different ports, hubs, cables etc. but nothing works.
So I thought maybe the pi isn't really sending data to the teensy's. So I install wireshark to check it but everything looks good. Every Teensy is responding to the "?" request and after that there is much communication between the pi und the Teensy's.

Can someone help?

Sorry, but english is not my native language.
 
You need to change these to the serial devices on the RPi

Code: 
  serialConfigure("/dev/tty.usbmodem4645681");  // change these to your port names
  serialConfigure("/dev/cu.usbmodem4645891");
  serialConfigure("/dev/tty.usbmodem4793111");

On Linux, they should be /dev/ttyACM0, /dev/ttyACM1, /dev/ttyACM2
 
On Linux, they should be /dev/ttyACM0, /dev/ttyACM1, /dev/ttyACM2
Click to expand...
Forget to change for this post. This is the last test from the Mac.
I changed this as well like /dev/ttyACM0 ..

For some reason it works only with one Teensy.

Do you have an other idea why this doesn't work?
 
Which version of Processing and MacOS do you have?

My testing Mac has 10.13.6.

I recently updated movie2serial.pde for Processing 3.4. Please make sure you have the latest version.

If that doesn't do it, please share the 3 config you have for the 3 Teensy boards. I can try running 3 boards here to see if I can reproduce the problem.
 
Status
Not open for further replies.
Back
Top