ADXL345 data rate is slightly off with SPI

[wowsk]

Hi all,
I am connecting a Teensy 3.2 with an ADXL345 accelerometer measuring at 25Hz. To start with I used I2C and the built in FIFO buffer on the ADXL345 to transfer 25 readings once 25 readings were stored in the buffer. It took almost exactly 1 second, plus or minus a couple hundred microseconds, to store the 25 readings which is what one would expect at 25Hz. This was great, but while the data was being transferred over I2C the accelerometer was not sampling and it took around 25ms to transfer the 25 readings. In other words we were losing a lot of data.

I decided to try SPI due to the increased speed at which it can transfer data, and sure enough the 25 readings were transferred in 300-1000 microseconds depending on the SPI clock speed. The only problem is now I am getting the 25 readings every 1022 milliseconds, not every 1000 like one would expect. I don't know if this is something wrong with my code, the SCK Pin, or the ADXL345.

Any help is appreciated.

Main Program:

//Add the SPI library so we can communicate with the ADXL345 sensor
#include <SPI.h>
#include "Accelerometer.h"

unsigned char values[10];
//This buffer will hold values read from the ADXL345 registers.
unsigned char buf [32][6];
//These variables will be used to hold the x,y and z axis accelerometer values.
int x,y,z;
double xg, yg, zg;

void setup(){ 
  //Initiate an SPI communication instance.
  SPI.begin();
  SPI.beginTransaction(SPISettings(1600000, MSBFIRST, SPI_MODE3));
  //Create a serial connection to display the data on the terminal.
  Serial.begin(5000000);
  InitAccel(values);
}

void readBuffer(char registerAddress, int numInBuffer){
  //Since we're performing a read operation, the most significant bit of the register address should be set.
  char address = 0x80 | registerAddress;
  //Since we're doing a multi-byte read, bit 6 needs to be set as well.
  address = address | 0x40;
  
  for(int i=0; i<numInBuffer; i++) {
  //Set the Chip select pin low to start an SPI packet.
  digitalWrite(CS, LOW);
  //Continue to read registers until we've read the number specified, storing the results to the input buffer.
    SPI.transfer(address);
    for(int j=0; j<6; j++){
      buf[i][j] = SPI.transfer(0x00);
    }
  //Set the Chips Select pin high to end the SPI packet.
  digitalWrite(CS, HIGH);
  }
}

float lastMicros=0;
float currMicros=0;

void loop(){
  readRegister(FIFO_STATUS,1,values);
  if(values[0]>=25) {
    currMicros = micros();
    Serial.println(currMicros-lastMicros);
    readBuffer(DATAX0, values[0]);
    lastMicros=micros();
    Serial.println(lastMicros-currMicros);
    for(int i=0; i<values[0]; i++) {
      //The ADXL345 gives 10-bit acceleration values, but they are stored as bytes (8-bits). To get the full value, two bytes must be combined for each axis.
      //The X value is stored in values[0] and values[1].
      x = tenBitTwosComplementToDecimal((((uint16_t)buf[i][1]<<8)|(uint16_t)buf[i][0]) & 1023);
      //The Y value is stored in values[2] and values[3].
      y = tenBitTwosComplementToDecimal((((uint16_t)buf[i][3]<<8)|(uint16_t)buf[i][2]) & 1023);
      //The Z value is stored in values[4] and values[5].
      z = tenBitTwosComplementToDecimal((((uint16_t)buf[i][5]<<8)|(uint16_t)buf[i][4]) & 1023);
      
      //Convert the accelerometer value to G's. 
      //With 10 bits measuring over a +/-4g range we can find how to convert by using the equation:
      // Gs = Measurement Value * (G-range/(2^10)) or Gs = Measurement Value * (8/1024)
      xg = x * 0.00390625;
      yg = y * 0.00390625;
      zg = z * 0.00390625;
      
          Serial.print((float)xg,2);
          Serial.print("g,");
          Serial.print((float)yg,2);
          Serial.print("g,");
          Serial.print((float)zg,2);
          Serial.println("g");
    }
  }
}

Accelerometer.h:

/**********************************************************************
 * File: Accelerometer.h
 * Date: 07/10/2019
 * Input: N/A
 * Outputs: See Variables
 * Purpose: Collect accelerometer data
 * 
    I2C Communication Accelerometer Tutorial
     by Dejan, https://howtomechatronics.com
     
 * 
    Basic Accel SPI Communication
    by hamaluik, https://gist.github.com/hamaluik/b1903a8353dc1ec57da8
**********************************************************************/

//ADXL345 Register Addresses
#define  DEVID   0x00  //Device ID Register
#define THRESH_TAP  0x1D  //Tap Threshold
#define OFSX    0x1E  //X-axis offset
#define OFSY    0x1F  //Y-axis offset
#define OFSZ    0x20  //Z-axis offset
#define DURATION  0x21  //Tap Duration
#define LATENT    0x22  //Tap latency
#define WINDOW    0x23  //Tap window
#define THRESH_ACT  0x24  //Activity Threshold
#define THRESH_INACT  0x25  //Inactivity Threshold
#define TIME_INACT  0x26  //Inactivity Time
#define ACT_INACT_CTL 0x27  //Axis enable control for activity and inactivity detection
#define THRESH_FF 0x28  //free-fall threshold
#define TIME_FF   0x29  //Free-Fall Time
#define TAP_AXES  0x2A  //Axis control for tap/double tap
#define ACT_TAP_STATUS  0x2B  //Source of tap/double tap
#define BW_RATE   0x2C  //Data rate and power mode control
#define POWER_CTL 0x2D  //Power Control Register
#define INT_ENABLE  0x2E  //Interrupt Enable Control
#define INT_MAP   0x2F  //Interrupt Mapping Control
#define INT_SOURCE  0x30  //Source of interrupts
#define DATA_FORMAT 0x31  //Data format control
#define DATAX0    0x32  //X-Axis Data 0
#define DATAX1    0x33  //X-Axis Data 1
#define DATAY0    0x34  //Y-Axis Data 0
#define DATAY1    0x35  //Y-Axis Data 1
#define DATAZ0    0x36  //Z-Axis Data 0
#define DATAZ1    0x37  //Z-Axis Data 1
#define FIFO_CTL  0x38  //FIFO control
#define FIFO_STATUS 0x39  //FIFO status

//Assign the Chip Select signal to pin 10.
int CS=10;
//This function will write a value to a register on the ADXL345.
//Parameters:
//  char registerAddress - The register to write a value to
//  char value - The value to be written to the specified register.
void writeRegister(char registerAddress, unsigned char value){
  //Set Chip Select pin low to signal the beginning of an SPI packet.
  digitalWrite(CS, LOW);
  //Transfer the register address over SPI.
  SPI.transfer(registerAddress);
  //Transfer the desired register value over SPI.
  SPI.transfer(value);
  //Set the Chip Select pin high to signal the end of an SPI packet.
  digitalWrite(CS, HIGH);
}
int16_t tenBitTwosComplementToDecimal(uint16_t x)
{
  boolean negative = (x & (1 << 9)) != 0;
  if(negative)
    return x | ~((1 << 10) - 1);
   return (int16_t)x;
}

//This function will read a certain number of registers starting from a specified address and store their values in a buffer.
//Parameters:
//  char registerAddress - The register addresse to start the read sequence from.
//  int numBytes - The number of registers that should be read.
//  char * values - A pointer to a buffer where the results of the operation should be stored.
void readRegister(char registerAddress, int numBytes, unsigned char * values){
  //Since we're performing a read operation, the most significant bit of the register address should be set.
  char address = 0x80 | registerAddress;
  //If we're doing a multi-byte read, bit 6 needs to be set as well.
  if(numBytes > 1)address = address | 0x40;
  
  //Set the Chip select pin low to start an SPI packet.
  digitalWrite(CS, LOW);
  //Transfer the starting register address that needs to be read.
  SPI.transfer(address);
  //Continue to read registers until we've read the number specified, storing the results to the input buffer.
  for(int i=0; i<numBytes; i++){
    values[i] = SPI.transfer(0x00);
  }
  //Set the Chips Select pin high to end the SPI packet.
  digitalWrite(CS, HIGH);
}

void InitAccel(unsigned char * values) {

  //Set up the Chip Select pin to be an output from the Arduino.
  pinMode(CS, OUTPUT);
  //Before communication starts, the Chip Select pin needs to be set high.
  digitalWrite(CS, HIGH);
  
  
  //Put the ADXL345 into +/- 2G range by writing the value 0x00 to the DATA_FORMAT register.
  writeRegister(DATA_FORMAT, 0x00);
  
  
  //Put the ADXL345 into Measurement Mode by writing 0x08 to the POWER_CTL register.
  writeRegister(POWER_CTL, 0x08); //Measurement mode

  // Set output rate to 25Hz
  writeRegister(BW_RATE, 0x08);  
  
  //Set to FIFO mode
  writeRegister(FIFO_CTL, 0x40);  
  
}

 

[UhClem]

The output data rate in the ADXL345 depends on its internal oscillator and the data sheet is silent on its accuracy and stability.