Teensy 4.0 and Ethernet (WIZ5100 and WIZ812)

Status
Not open for further replies.

floemse

New member
Dear Forum,

I'm new into Teensy. I did some Arduino Projects, also with Ethernet, mostly with the WIZ5100 and the standard Ethernet library from the Aruino IDE. For a new project I needed some more "power" and I decided to use a Teensy 4.0 for this. Works very well, the only issue I have now is the Ethernet connection. I used a module with a WIZ5100 chip which worked very well with a standard Arduino DUE and tested this with the Webserver and Webclient examples. Both worked well, so I'm sure the hardware should not be damaged, I also use a second module, the same.

Now I'm not able to get this WIZ5100 module running with the Teensy 4.0. Ok, so I bought a newer module with the WIZ812 chip with the same result, I can't get it running. Has anybody any hint what I'm doing wrong? As written above, the code and also the modules seems to work, just in combination with the Teensy 4.0 I don't have any success.
Output on the serial console:
Ethernet WebServer Example
server is at 192.168.0.0
That’s all… I don’t even understand, why the IP is not compete?

The Webclient example can't connect to google.com, the same example with the DUE worked fine.

Thank you very much for any help.


Hardware:
Teensy 4.0
https://www.digikey.com/en/products/detail/sparkfun-electronics/DEV-15583/10384551
WIZ812MJ
https://www.digikey.com/en/products/detail/wiznet/WIZ812MJ/3829654

Wiring is done with wire wrap wires:
Teensy -> WIZ812MJ
GND -> J1,11 (GND)
3.3V -> J1,12 (3V3D)
10 (CS) -> J2,4 (/SCS)
11 (MOSI) -> J1,1 (MOSI)
12 (MISO) -> J1,2 (MISO)
13 (SCK) -> J2,3 (SCLK)
9 -> J2,2 (/RESET)
I connected the Reset Pin of the WIZ812 Board to pin 9 of the Teensy.

Code:
Code:
/*
  Web Server

 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 modified 02 Sept 2015
 by Arturo Guadalupi
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 0, 37);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
  // You can use Ethernet.init(pin) to configure the CS pin
  //Ethernet.init(10);  // Most Arduino shields
  //Ethernet.init(5);   // MKR ETH shield
  //Ethernet.init(0);   // Teensy 2.0
  //Ethernet.init(20);  // Teensy++ 2.0
  //Ethernet.init(15);  // ESP8266 with Adafruit Featherwing Ethernet
  //Ethernet.init(33);  // ESP32 with Adafruit Featherwing Ethernet

  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }
  Serial.println("Ethernet WebServer Example");

  pinMode(9, OUTPUT);
  digitalWrite(9, LOW); 
  delay(100);           
  digitalWrite(9, HIGH);
  delay(100);

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);

  // Check for Ethernet hardware present
  if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); // do nothing, no point running without Ethernet hardware
    }
  }
  if (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
  }

  // start the server
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}
 
Last edited:
Looks like W5100 may be not working with Teensy 4.0.

I tested just now. W5200 & W5500 definitely do work with Teensy 4.0, but W5100 doesn't seem to initialize.

All 3 work work with Teensy LC & 3.2.
 
Looks like we may be doing something too fast for that old W5100 chip.

I did get W5100 to work with Teensy 4.0 by setting Tools > CPU Speed to 150 MHz.


And to answer your question:

Do I understand this correctly, that no one has used a Teensy 4.0 in combination with a WIZ Chip?

It's been used many times with W5500, which is the chip almost everyone using Wiznet chooses these days, because it's less expensive and performs much better than the ancient W5100 chip.

Looks like W5100 has been broken for running at full clock speed for quite some time, but nobody noticed until now. That's how rare W5100 usage is these days.
 
Ok, here's a fix. Find w5100.h. It should be in {Arduino}/hardware/teensy/avr/libraries/Ethernet/src/utility. Search in the file for "__IMXRT1062__" and edit the resetSS function like this:

Code:
#elif defined(__IMXRT1062__)
        static volatile uint32_t *ss_pin_reg;
        static uint32_t ss_pin_mask;
        inline static void initSS() {
                ss_pin_reg = portOutputRegister(digitalPinToPort(ss_pin));
                ss_pin_mask = digitalPinToBitMask(ss_pin);
                pinMode(ss_pin, OUTPUT);
        }
        inline static void setSS() {
                *(ss_pin_reg+34) = ss_pin_mask;
        }
        inline static void resetSS() {
                *(ss_pin_reg+33) = ss_pin_mask;
                if (chip == 51) delayNanoseconds(10); // <-- fixes W5100 on Teensy 4
        }

I've committed a fix on github, so this will be in all future Teensyduino releases.

https://github.com/PaulStoffregen/Ethernet/commit/525279c940989c363b1b7031657bf2799642910d
 
Sorry for the delayed reply, I was offline for a few days.
@PaulStoffregen: Thank you for your detailed tests and support!

The 600MHz CPU speed is one of the reasons I have selected the Teensy 4.0, therefor, a reduction of speed is not a solution for me.

I will try your fix today, looking forward for some positive results. :)
 
@PaulStoffregen: The WIZ5100 works now with my Teensy 4! :)
The delay was necessary, perfect, thank you very much.
 
Status
Not open for further replies.
Back
Top