Need help getting adafruit DS3231 RTC working on wire2

[jrdarrah]

I have a Adafruit DS3231 RTC connected to a teensy 4.1 on wire 2. The I2C scanner program sees the clock and a pressure sensor also on Wire2. I'm trying to compile the DS3231 example supplied by RTCLib.h and can't seem to get the rtc.begin statement syntax correct. My latest attempt is:

// Date and time functions using a DS3231 RTC connected via I2C and Wire lib
#include <Wire.h>
#include "RTClib.h"

RTC_DS3231 rtc;

char daysOfTheWeek[7][12] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

void setup () {
  Wire2.begin();
  Serial.begin(57600);

#ifndef ESP8266
  while (!Serial); // wait for serial port to connect. Needed for native USB
#endif

  if (! rtc.begin(Wire2)) {
    Serial.println("Couldn't find RTC");
    Serial.flush();
    while (1) delay(10);
  }

  if (rtc.lostPower()) {
    Serial.println("RTC lost power, let's set the time!");
    // When time needs to be set on a new device, or after a power loss, the
    // following line sets the RTC to the date & time this sketch was compiled
    rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
    // This line sets the RTC with an explicit date & time, for example to set
    // January 21, 2014 at 3am you would call:
    // rtc.adjust(DateTime(2014, 1, 21, 3, 0, 0));
  }

  // When time needs to be re-set on a previously configured device, the
  // following line sets the RTC to the date & time this sketch was compiled
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  // This line sets the RTC with an explicit date & time, for example to set
  // January 21, 2014 at 3am you would call:
  // rtc.adjust(DateTime(2014, 1, 21, 3, 0, 0));
}

void loop () {
    DateTime now = rtc.now();

    Serial.print(now.year(), DEC);
    Serial.print('/');
    Serial.print(now.month(), DEC);
    Serial.print('/');
    Serial.print(now.day(), DEC);
    Serial.print(" (");
    Serial.print(daysOfTheWeek[now.dayOfTheWeek()]);
    Serial.print(") ");
    Serial.print(now.hour(), DEC);
    Serial.print(':');
    Serial.print(now.minute(), DEC);
    Serial.print(':');
    Serial.print(now.second(), DEC);
    Serial.println();

    Serial.print(" since midnight 1/1/1970 = ");
    Serial.print(now.unixtime());
    Serial.print("s = ");
    Serial.print(now.unixtime() / 86400L);
    Serial.println("d");

    // calculate a date which is 7 days, 12 hours, 30 minutes, 6 seconds into the future
    DateTime future (now + TimeSpan(7,12,30,6));

    Serial.print(" now + 7d + 12h + 30m + 6s: ");
    Serial.print(future.year(), DEC);
    Serial.print('/');
    Serial.print(future.month(), DEC);
    Serial.print('/');
    Serial.print(future.day(), DEC);
    Serial.print(' ');
    Serial.print(future.hour(), DEC);
    Serial.print(':');
    Serial.print(future.minute(), DEC);
    Serial.print(':');
    Serial.print(future.second(), DEC);
    Serial.println();

    Serial.print("Temperature: ");
    Serial.print(rtc.getTemperature());
    Serial.println(" C");

    Serial.println();
    delay(3000);
}

I get this error at compile time

ds3231_rtc:17: error: no matching function for call to 'RTC_DS3231::begin(TwoWire&)'
if (! rtc.begin(Wire2)) {
^
In file included from C:\Users\james\Documents\Arduino\ds3231_rtc\ds3231_rtc.ino:3:0:
C:\Users\james\Documents\Arduino\libraries\RTClib-master\src/RTClib.h:372:8: note: candidate: bool RTC_DS3231::begin(TwoWire*)
bool begin(TwoWire *wireInstance = &Wire);
^
C:\Users\james\Documents\Arduino\libraries\RTClib-master\src/RTClib.h:372:8: note: no known conversion for argument 1 from 'TwoWire' to 'TwoWire*'

RTClib.h gives this definition

  bool begin(TwoWire *wireInstance = &Wire);

What is the proper syntax for the rtc.begin() given I want to communicate on Wire2?

 

[thebigg]

rtc.begin(&Wire2)

 

[jrdarrah]

Thanks, thebigg. That got it working. I appreciate the help.