Forum Rule: Always post complete source code & details to reproduce any issue!
Page 2 of 2 FirstFirst 1 2
Results 26 to 29 of 29

Thread: GPS working!

  1. #26
    Junior Member keeb's Avatar
    Join Date
    Dec 2013
    Posts
    19
    How it's wired up...
    Click image for larger version. 

Name:	IMG_20131219_212145_922.jpg 
Views:	283 
Size:	175.5 KB 
ID:	1235

    I commented out the "char c = gps.read()" line as suggested by Pete. (I now recall that earlier I had the whole thing commented out because now I'm back to what's shown below. I'm getting everything before the "if gps.fix" line, but nothing printed to the serial monitor after that. I was worried that I'd mucked up my library files by poking around them, so I replaced them with fresh copies. The only thing I changed was the case for the "isDigit" and "isAlpha" lines, so that the sketch would compile. Now I just get this. It is like the teensy just never gets the NMEA data from the gps, but I'm at a loss why not. Is there a very simple way to just print the raw data from the module, to see if I can get that far? The adafruit library contains a "blank" sketch for this purpose that just bypasses everything let the serial monitor print whatever comes its way. What would be the teensy version of this?

    Code:
    $PMTK605*31
    
    Time: 0:0:0.0
    Date: 0/0/200
    Fix: 0 quality: 0
    
    Time: 0:0:0.0
    Date: 0/0/200
    Fix: 0 quality: 0
    
    Time: 0:0:0.0
    Date: 0/0/200
    Fix: 0 quality: 0
    
    Time: 0:0:0.0
    Date: 0/0/200
    Fix: 0 quality: 0
    adafruit "Blank" sketch for viewing raw gps data over serial (can I do something similar on Teensy to test?):
    Code:
    // this sketch will allow you to bypass the Atmega chip
    // and connect the GPS sensor directly to the USB/Serial
    // chip converter.
    
    // Connect VIN to +5V
    // Connect GND to Ground
    // Connect GPS RX (data into GPS) to Digital 0
    // Connect GPS TX (data out from GPS) to Digital 1
    
    void setup() {}
    void loop() {}

  2. #27
    Senior Member PaulStoffregen's Avatar
    Join Date
    Nov 2012
    Posts
    25,082
    That photos really helps! I believe you need to swap the 2 signal wires. You've got RX from Adafruit's GPS connected to RX on the Teensy3, and likewise TX connected to TX.

    What you really need is TX from one connected to RX on the other, and vice verse, so each side transmits to the pin where the other side is trying to receive.

  3. #28
    Senior Member PaulStoffregen's Avatar
    Join Date
    Nov 2012
    Posts
    25,082
    Also, it looks like you've got VIN on Adafruit's GPS connected to 3.3V on Teensy3. That might work fine, and it's probably the safest way to use this. Adafruit claims this thing works down to 3.0 volts.

    It looks like they put a 3.3 volt regulator on the board, meant to create 3.3V from 5.0V. You might check the 3.3V pin to see what voltage the GPS is actually getting from its own regulator. If it's lower than 3.0V, you might need to connect VIN to Teensy3's VIN or VUSB pin.

    But swap those signal wires first. That will probably solve all your troubles.

  4. #29
    Junior Member keeb's Avatar
    Join Date
    Dec 2013
    Posts
    19
    Thanks so much for the help. It works just fine now after switching the serial receive and transmit wires as Paul suggested. I'm gonna chalk this one up to being a complete noob. Just in case anybody else stumbles across this thread in need of help, here's what finally worked for me.

    Edited the Adafruit_gps.cpp files as follows:
    Code:
    char c = response[0];
          if (isdigit(c))              //changed from isDigit
            parsed[i] += c - '0';
          else
            parsed[i] = c;
          response++;
    Code:
    LOCUS_serial = parsed[0];
      LOCUS_type = parsed[1];
      if (isalpha(parsed[2])) {       //changed from isAlpha
        parsed[2] = parsed[2] - 'a' + 10;
    (I also changed altitude from meters to feet, and speed from knots to mph by multiplying the respective variables by the appropriate conversion factors.)

    The modified adafruit parsing sketch:
    Code:
    // Test code for Adafruit GPS modules using MTK3329/MTK3339 driver
    //
    // This code shows how to listen to the GPS module in an interrupt
    // which allows the program to have more 'freedom' - just parse
    // when a new NMEA sentence is available! Then access data when
    // desired.
    //
    // Tested and works great with the Adafruit Ultimate GPS module
    // using MTK33x9 chipset
    //    ------> http://www.adafruit.com/products/746
    // Pick one up today at the Adafruit electronics shop 
    // and help support open source hardware & software! -ada
    
    #include <Adafruit_GPS.h>
    #include <SoftwareSerial.h>
    
    
    // If you're using a GPS module:
    // Connect the GPS Power pin to 5V
    // Connect the GPS Ground pin to ground
    // If using software serial (sketch example default):
    //   Connect the GPS TX (transmit) pin to Digital 3
    //   Connect the GPS RX (receive) pin to Digital 2
    // If using hardware serial (e.g. Arduino Mega):
    //   Connect the GPS TX (transmit) pin to Arduino RX1, RX2 or RX3
    //   Connect the GPS RX (receive) pin to matching TX1, TX2 or TX3
    
    // If you're using the Adafruit GPS shield, change 
    // SoftwareSerial mySerial(3, 2); -> SoftwareSerial mySerial(8, 7);
    // and make sure the switch is set to SoftSerial
    
    // If using software serial, keep these lines enabled
    // (you can change the pin numbers to match your wiring):
    //SoftwareSerial mySerial(3, 2);
    
    //Adafruit_GPS GPS(&mySerial);
    // If using hardware serial (e.g. Arduino Mega), comment
    // out the above six lines and enable this line instead:
    Adafruit_GPS GPS(&Serial1);
    
    
    // Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
    // Set to 'true' if you want to debug and listen to the raw GPS sentences. 
    #define GPSECHO  true
    
    // this keeps track of whether we're using the interrupt
    // off by default!
    boolean usingInterrupt = false;
    void useInterrupt(boolean); // Func prototype keeps Arduino 0023 happy
    
    void setup()  
    {
    
      // connect at 115200 so we can read the GPS fast enough and echo without dropping chars
      // also spit it out
      Serial.begin(115200);
      Serial.println("Adafruit GPS library basic test!");
    
      // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
      GPS.begin(9600);
    
      // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data) including altitude
      GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
      // uncomment this line to turn on only the "minimum recommended" data
      //GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
      // For parsing data, we don't suggest using anything but either RMC only or RMC+GGA since
      // the parser doesn't care about other sentences at this time
    
      // Set the update rate
      GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ);   // 1 Hz update rate
      // For the parsing code to work nicely and have time to sort thru the data, and
      // print it out we don't suggest using anything higher than 1 Hz
    
      // Request updates on antenna status, comment out to keep quiet
      GPS.sendCommand(PGCMD_ANTENNA);
    
      // the nice thing about this code is you can have a timer0 interrupt go off
      // every 1 millisecond, and read data from the GPS for you. that makes the
      // loop code a heck of a lot easier!
      //useInterrupt(true);
    
      delay(1000);
      // Ask for firmware version
      //Serial.println(PMTK_Q_RELEASE);
    }
    
    
    uint32_t timer = millis();
    void loop()                     // run over and over again
    {
      // in case you are not using the interrupt above, you'll
      // need to 'hand query' the GPS, not suggested :(
      if (! usingInterrupt) {
        // read data from the GPS in the 'main loop'
        char c = GPS.read();
        // if you want to debug, this is a good time to do it!
        if (GPSECHO)
          if (c) Serial.print(c);
      }
    
      // if a sentence is received, we can check the checksum, parse it...
      if (GPS.newNMEAreceived()) {
        // a tricky thing here is if we print the NMEA sentence, or data
        // we end up not listening and catching other sentences! 
        // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
        //Serial.println(GPS.lastNMEA());   // this also sets the newNMEAreceived() flag to false
    
        if (!GPS.parse(GPS.lastNMEA()))   // this also sets the newNMEAreceived() flag to false
          return;  // we can fail to parse a sentence in which case we should just wait for another
      }
    
      // if millis() or timer wraps around, we'll just reset it
      if (timer > millis())  timer = millis();
    
      // approximately every 2 seconds or so, print out the current stats
      if (millis() - timer > 1000) { 
        timer = millis(); // reset the timer
    
    
        Serial.print("\nTime: ");
        Serial.print(GPS.hour, DEC); 
        Serial.print(':');
        Serial.print(GPS.minute, DEC); 
        Serial.print(':');
        Serial.print(GPS.seconds, DEC); 
        Serial.print('.');
        Serial.println(GPS.milliseconds);
        Serial.print("Date: ");
        Serial.print(GPS.day, DEC); 
        Serial.print('/');
        Serial.print(GPS.month, DEC); 
        Serial.print("/20");
        Serial.println(GPS.year, DEC);
        Serial.print("Fix: "); 
        Serial.print((int)GPS.fix);
        Serial.print(" quality: "); 
        Serial.println((int)GPS.fixquality); 
        if (GPS.fix) {
          Serial.print("Location: ");
          Serial.print(GPS.latitude, 4); 
          Serial.print(GPS.lat);
          Serial.print(", "); 
          Serial.print(GPS.longitude, 4); 
          Serial.println(GPS.lon);
    
          Serial.print("Speed (MPH): "); 
          Serial.println(GPS.speed);
          Serial.print("Angle: "); 
          Serial.println(GPS.angle);
          Serial.print("Altitude (Ft): "); 
          Serial.println(GPS.altitude);
          Serial.print("Satellites: "); 
          Serial.println((int)GPS.satellites);
    
        }  
      }
    }

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •